실시간(Real Time) 운영체제(OS) 의 RTOS와 FreeRTOS 사용해보기

<본 블로그는 콩이의 일상과 임베디드 blog ,  EmbeddedJune의 Festival  블로그를 참고해서 공부하며 작성하였습니다 :-)>

 

⭐ RTOS

실시간(Real Time) 운영체제(Operating System)의 약자

제한된 시간내에 원하는 작업을 모두 처리하는것을 보장하는 운영체제

멀티태스킹 환경에서 Task 처리시간을 일관되게 유지하기 위한 용도로 사용

시분할 시스템 하에서 우선순위 기반 스케줄링을 통해 우선순위가 높은 task가 먼저 작업을 처리할 수 있게 함

스케줄링 : 프로세스들에게 CPU 등 자원을 배정하는 것을 말함

 

동시에 여러가지 응용 프로그램을 사용하다보면 처리속도가 지연되거나 프로그램실행이 1초 이상 지연됨

RTOS를 사용한 기기는 응용 프로그램을 최대 1초안에 처리하는 것을 보장한다

윈도우나 리눅스에서는 millisecond, microsecond 단위로 프로그램을 제어하는 것은 어렵지만, RTOS에서는 가능

 

⭐ FreeRTOS

RTOS의 종류가 있는데 RTOS앞에 Free 라는 수식어가 붙은 이유는 누구나 사용가능

소형 저출력 엣지 디바이스를 쉽게 프로그래밍, 배포, 보호, 연결 및 관리할 수 있는 마이크로 컨트롤러용 실시간 오픈 소스 운영 체제

2003년 Richard Barry가 만든 ANSI C 기반 RTOS

아마존 AWS IoT 서비스 확장을 위해 2017년 11월에 인수

 

 - 기타 고성능 OS(Linux, Windows, iOS, Android 등)와는 다르게 1초 내에 Task의 작업을 끝내는 것을 보장

(단순히 빨리 끝내는것이 아니라 작업의 처리를 보장)

 - 실시간 처리가 필요한 시스템(국방 시스템, 안전보조장치 등)에 많이 사용

 - RTOS가 활용되는 기기는 거의 대부분 임베디드 시스템

 - 응용 프로그램의 처리 요청을 정해진 시간내에 끝마칠 수 있는 성능에 중점

 - 선점형 멀티 태스킹을 지원하고 각 프로세스의 실행 순서를 지정해 효율적인 처리가 가능

 - 100% 완전 무료이고, 보증 및 기술적인 법적보호는 지원하지 않는다

 

🌳 태스크 (Task)

FreeRTOS에서 하나의 task는 하나의 스레드(thread)를 의미

 

1️⃣ 각 task에는 우선순위를 할당하며 숫자가 높을수록 큰 우선순위를 의미한다.

우선순위는 0부터 configMAX_PRIORITIES까지 할당이 가능하다.

우선순위가 높은 task는 낮은 task를 선점(preemption)할 수 있고, 이때 context switching이 발생

동일한 우선순위 사이에서는 round robin을 사용

 

2️⃣ Task는 return value가 없으며 (void*) 타입으로 여러 자료형을 매개변수로 받을 수 있다

3️⃣ Task는 일회용 task와 주기적 task 2가지 종류

1) 일회용 task는 기능을 한 번 수행한 뒤 마지막에 스스로를 삭제한다 (꼭)

void 태스크이름( void* pvParameters ) { /* ~~~ */ vTaskDelete(NULL); }

2) 주기적 task는 무한 loop가 들어있다

Delay 또는 suspend 함수 등으로 task의 state가 blocked(waiting)로 변하지 않는 이상 계속해서 기능을 빠르게 반복 실행

void 태스크이름( void* pvParameters ) { while(true) { /* ~~~~~ */ } }

 

4️⃣ 각 task마다 local stack 공간이 할당

이 공간은 메모리의 .bss영역 또는 .heap 영역에 들어간다

Stack 메모리는 정적 또는 동적으로 할당이 가능

 

🌳태스크 (Task) 관련 API

1️⃣ xTaskCreate

    /* Create our tasks. */
    xTaskCreate(
        vTaskBlink,                 /* Pointer to the Task implementation. */
        "Blink",                    /* Internal name of the task. */
        configMINIMAL_STACK_SIZE,   /* Wanted task stack size. */
        NULL,                       /* Task parameter (optional). */
        1,                          /* Task priority. */
        NULL                        /* Task handle (optional). */
    );

freertos.ino - VxWorks

pvTaskCode : task의 기능이 선언된 함수의 함수포인터

pcName : 디버깅 용도로 사용하는 문자열이며 task의 이름

usStackDepth :  task마다 할당되는 stack 메모리

(단위는 WORD이며 ARM Cortex-M보드에서는 1WORD == 4Byte)

pvParameters : task 함수로 전달할 매개변수

없다면 NULL

전달할 매개변수를 (void*) 타입으로 캐스팅한 뒤 여기다가 넣어주면 task 함수에서 사용

pxCreatedTaskV : task를 제어하기 위한 TaskHandle_t 타입 핸들

Task의 우선순위를 바꾸거나, task를 멈추거나 등 task에 대한 설정은 모두 이 핸들을 통해서 이뤄진다.

 

2️⃣ vTaskDelay

/* Delay the task 1000ms to create a 1Hz blinking. */
vTaskDelay( 1000 / portTICK_PERIOD_MS );

Task의 상태를 running에서 blocked(waiting)으로 변경하는 함수

설정된 시간 xTicksToDelay동안 해당 task는 blocked task가 되며, 다음 우선순위를 가진 task가 실행

 

확장성 및 이식성 좋은 코드를 만들기 위해서 tick단위 시간을 사용하는 것 보다 pdMS_TO_TICKS() 매크로를 사용해서 우리에게 편한 ms(밀리초) 단위를 tick으로 변환해서 사용하는 것이 좋다

=> 왜냐하면, 사용하는 보드와 사용자 환경설정 값에 따라 1 Tick이 의미하는 시간이 다르기 때문

 

🌳 CODE ( freertos.ino - VxWorks)

// 멀티태스킹 환경에서 Task 처리시간을 일관되게 유지하기 위한 용도로 사용
// 실시간(Real Time) 운영체제(Operating System)의 약자
#include <Arduino_FreeRTOS.h>

/*-----------------------------------------------------------*/

void vTaskBlink( void * pvParameters );
void vTaskAnalogRead( void * pvParameters );

/*-----------------------------------------------------------*/

void setup( void )
{
    /* Initialize the serial port. */
    Serial.begin( 9600 );

    /* Create our tasks. */
    xTaskCreate(
        vTaskBlink,                 /* Pointer to the Task implementation. */
        "Blink",                    /* Internal name of the task. */
        configMINIMAL_STACK_SIZE,   /* Wanted task stack size. */
        NULL,                       /* Task parameter (optional). */
        1,                          /* Task priority. */
        NULL                        /* Task handle (optional). */
    );

    xTaskCreate( vTaskAnalogRead, "Analog", configMINIMAL_STACK_SIZE, NULL, 1, NULL );

    /* Start the kernel sheduler. */
    vTaskStartScheduler();
}
/*-----------------------------------------------------------*/

void loop( void )
{
    /* The Arduino loop function is used as the idle hook. In FreeRTOSConfig.h
    configUSE_IDLE_HOOK must be set because there are (serial) events that were
    processed in the backround of the Arduino core implementation of loop(). */
}
/*-----------------------------------------------------------*/

void vTaskBlink( void * pvParameters )
{
    /* Initialize the built in LED. */
    pinMode( LED_BUILTIN, OUTPUT );

    /* Keep the compiler happy because pvParameters is not used here. */
    ( void ) pvParameters;

    for( ;; )
    {
        /* Toggle the built in LED. */
        digitalWrite( LED_BUILTIN, digitalRead( LED_BUILTIN ) ^ 1 );

        /* Delay the task 1000ms to create a 1Hz blinking. */
        vTaskDelay( 1000 / portTICK_PERIOD_MS );
    }
}
/*-----------------------------------------------------------*/

void vTaskAnalogRead( void * pvParameters )
{
    int16_t sAnalogValue;

    /* Keep the compiler happy because pvParameters is not used here. */
    ( void ) pvParameters;

    for( ;; )
    {
        /* Read the analog value from A0 print it out. */
        sAnalogValue = analogRead( A0 );
        Serial.println( sAnalogValue );

        /* Short delay for stability. */
        vTaskDelay( 1 );
    }
}