CAN (Controller Area Network) 이란? with Arduino UNO R4 WIFI

<본 블로그는 LUFT-AQUILA  블로그를 참고해서 공부하며 작성하였습니다 :-)>

 

⭐ CAN (Controller Area Network)

차량 내에서 호스트 컴퓨터 없이 마이크로 컨트롤러 장치들이 서로 통신하기 위해 설계된 표준 통신 규격

메시지 기반 프로토콜

 

🌳 특징

1️⃣ 시리얼 통신 기반, 같은 버스라인 통해 전송 및 수신

2️⃣ Multi-Master, 통신 버스를 여러 노드들이 공유한다

3️⃣ 간단하고 노이즈에 강하다

twist pair 을 사용하며, CANH 와 CAHL 의 2개 선으로 통신한다

4️⃣ ID 값 이용한 우선 순위를 매긴다

ECU 는 고유한 ID 를 가진다

ID가 낮을수록 우선순위가 높다

주소가 아닌 ID로 메시지를 관리한다

나머지는 다음 bus cycle 에 재전송한다

5️⃣ CSMA (Carrier Sense Multiple Access) & CS/CD

6️⃣ 최대 8byte, 비동기식 직렬, 주소지정 X

7️⃣ transceiver 을 통해 차동신호를 MCU 가 이해가는 디지털 신호로 변경해준다

8️⃣ 양 끝단에 120 저항을 연결한다

임피던스 매칭위해 종단 저항은 필수이다

9️⃣ CAN 은 GND 가 없다

CANH와 CANL 전압차로 신호 (차동 신호) 를 만든다

전압차 없으면 LOW

전압차 있으면 HIGH

🔟 데이터 필드

 

 

🌳 CODE

참고로 저 arduino 는 arduino uno r4 wifi 이다

can 통신이 내장되어 있다

// CAN_WRITE

//#include <R7FA2A1AB.h>
#include <Arduino_CAN.h>

/**************************************************************************************
 * CONSTANTS
 **************************************************************************************/

// 캔 통신에서 송신되는 메세지는 ID가 있으며, 최대 8바이트의 데이터
// 메세지는 버스에 연결된 모든 제어기에게 전송
static uint32_t const CAN_ID = 0x23;

/**************************************************************************************
 * SETUP/LOOP
 **************************************************************************************/

void setup()
{
  // TRNG

  Serial.begin(115200);
  while (!Serial)
  {
  }

  // CAN 비트 전송률과 초기 라이브러리
  // CAN 트랜시버가 없으면 다른 CAN 장치와 통신할 수 없음! BR_125k (125000), BR_250k (250000), BR_500k(500000), BR_1000k (1000000)  """
  if (!CAN.begin(CanBitRate::BR_500k))
  {
    Serial.println("CAN.begin(...) failed.");
    for (;;)
    {
    }
  }
}

static uint32_t msg_cnt = 0;

void loop()
{
  //  매번 증가하는 CAN 메시지를 생성
  /* Assemble a CAN message with the format of
   * 0xCA 0xFE 0x00 0x00 [4 byte message counter]
   */
  uint8_t const msg_data[] = {0xCA, 0xFE, 0, 0, 0, 0, 0, 0};

  // 복사 받을 메모리를 가리키는 포인터, 복사할 메모리를 가리키고 있는 포인터, 복사할 데이터(값)의 길이(바이트 단위)
  memcpy((void *)(msg_data + 4), &msg_cnt, sizeof(msg_cnt));
  // CAN 메시지 보낼 객체(CanMsg) : CAN_ID, 크기 및 메시지 데이터
  CanMsg const msg(CanStandardId(CAN_ID), sizeof(msg_data), msg_data);

  /* Transmit the CAN message, capture and display an
   * error core in case of failure.
   */

  // 메시지를 보내기
  if (int const rc = CAN.write(msg); rc < 0)
  {
    Serial.print("CAN.write(...) failed with error code ");
    Serial.println(rc);
    for (;;)
    {
    }
  }

  /* Increase the message counter. */
  msg_cnt++;

  /* Only send one message per second. */
  delay(1000);
}

 

/*
  CANRead

  Receive and read CAN Bus messages

  See the full documentation here:
  https://docs.arduino.cc/tutorials/uno-r4-wifi/can
*/

/**************************************************************************************
 * INCLUDE
 **************************************************************************************/

#include <Arduino_CAN.h>

/**************************************************************************************
 * SETUP/LOOP
 **************************************************************************************/

void setup()
{
  Serial.begin(115200);
  while (!Serial) { }

  if (!CAN.begin(CanBitRate::BR_500k))
  {
    Serial.println("CAN.begin(...) failed.");
    for (;;) {}
  }
}

void loop()
{
  // 데이터가 사용 가능한지 확인
  if (CAN.available())
  {
    // 메시지를 읽기
    CanMsg const msg = CAN.read();
    Serial.println(msg);
  }
}